Faceit mouse_event aimbot для AutoIt

liebreich · 28 Май 2017

Этот аимбот будет UNDETECT на Faceit (и как всегда это не точно)
Сурсы:

Код:

#cs ----------------------------------------------------------------------------
 
 AutoIt Version: 3.3.14.2
 Author:         Requi
 
 Script Function:
    it´s a meme you dip
 
#ce ----------------------------------------------------------------------------
#RequireAdmin
 
#include "YatoMemory.au3"
#include <Misc.au3>
#include <WinAPI.au3>
 
Global $Vector2D = DllStructCreate("struct; float X; float Y; endstruct")
Global $Vector3D = DllStructCreate("struct; float X; float Y; float Z;endstruct")
Global $BoneMatrix = DllStructCreate("struct; float junk01[3]; float X; float junk02[3]; float Y; float junk03[3]; float Z; endstruct")
Global $ViewMatrix = DllStructCreate("struct; float M11; float M12; float M13; float M14; float M21; float M22; float M23; float M24; float M31; float M32; float M33; float M34; float M41; float M42; float M43; float M44; endstruct")
 
Const $LocalPlayer = 0x00A3343C
Const $EntityList = 0x04A50D24
Const $ViewMatrixOffset = 0x04A428D4
Const $PunchAngleOffset = 0x3018
Const $BoneMatrixOffset = 0x2698
Const $TeamOffset = 0xF0
Const $HealthOffset = 0xFC
Const $DormantOffset = 0xE9
 
Local $hDLL = DllOpen("user32.dll")
 
$ClientDll = 0
 
ConsoleWrite("  Looking for Counter-Strike Global Offensive...")
 
While Not _MemorySelectProcess("csgo.exe")
    Sleep(100)
WEnd
 
While Not $ClientDll
    $ClientDll = _MemoryGetModuleBase("bin\client.dll")
WEnd
 
ConsoleWrite("\n  Found and attached to it!")
 
AimbotLoop()
 
Func AimbotLoop()
    While True
        Sleep(1)
        If Not _IsPressed(1, $hDLL) Then
            ContinueLoop
        EndIf
 
        $closestEntity = GetClosestTarget()
        If $closestEntity = 0 Then
            ContinueLoop
        EndIf
        $hitbox = GetBonePos($closestEntity, 6)
        $w2sHitbox = WorldToScreen($hitbox)
        $punchAngle = GetPunchAngle()
 
        If $w2sHitbox.X = 0 And $w2sHitbox.Y = 0 Then
            ContinueLoop
        Endif
 
        $dy =   @desktopHeight / 90
        $dx =   @desktopWidth / 90
        $w2sHitbox.X += $dx * $punchAngle.Y
        $w2sHitbox.Y -= $dy * $punchAngle.X
 
 
        $aimPoint = ScreenToDelta($w2sHitbox)
        _WinAPI_Mouse_Event($MOUSEEVENTF_MOVE, $aimPoint.X, $aimPoint.Y)
 
    WEnd
EndFunc
 
Func ScreenToDelta($from)
    $ScreenCenterX =    @desktopWidth / 2
    $ScreenCenterY =    @desktopHeight / 2
    $TargetX = 0;
    $TargetY = 0;
    If $from.X <> 0 Then
        If $from.X > $ScreenCenterX Then
            $TargetX = -($ScreenCenterX - $from.X)
            If $TargetX + $ScreenCenterX > $ScreenCenterX * 2 Then
                $TargetX = 0
            Endif
        EndIf
 
        If $from.X < $ScreenCenterX Then
            $TargetX = $from.X - $ScreenCenterX;
            If $TargetX + $ScreenCenterX < 0 Then
                $TargetX = 0;
            EndIf
        Endif
    EndIf
 
    If $from.Y <> 0 Then
        If $from.Y > $ScreenCenterY Then
            $TargetY = -($ScreenCenterY - $from.Y)
            If $TargetY + $ScreenCenterY > $ScreenCenterY * 2 Then
                $TargetY = 0
            EndIf
        EndIf
 
        If $from.Y < $ScreenCenterY Then
            $TargetY = $from.Y - $ScreenCenterY
            If $TargetY + $ScreenCenterY < 0 Then
                $TargetY = 0
            EndIf
        EndIf
    EndIf
 
    $to = DllStructCreate("struct; float X; float Y; endstruct")
    $to.X = $TargetX
    $to.Y = $TargetY
    Return $to
EndFunc
 
Func WorldToScreen($from)
    $vMatrix = _MemoryReadStruct($ViewMatrix, $ClientDll + $ViewMatrixOffset)
    $vec2 = DllStructCreate("struct; float X; float Y; endstruct")
    $vec2.X = 0.0
    $vec2.Y = 0.0
 
    $m41 = $vMatrix.M41 * $from.X + $vMatrix.M42 * $from.Y + $vMatrix.M43 * $from.Z + $vMatrix.M44;
    If $m41 >= 0.01 Then
        $single = 1 / $m41;
        $m11 = ($vMatrix.M11 * $from.X + $vMatrix.M12 * $from.Y + $vMatrix.M13 * $from.Z + $vMatrix.M14) * $single
        $m21 = ($vMatrix.M21 * $from.X + $vMatrix.M22 * $from.Y + $vMatrix.M23 * $from.Z + $vMatrix.M24) * $single
        $vec2.X = ($m11 + 1) * 0.5 *   @desktopWidth
        $vec2.Y = ($m21 - 1) * -0.5 *   @desktopHeight
    EndIf
 
    Return $vec2
EndFunc
 
Func GetClosestTarget()
    $returnEntity = 0
    $maxDistance = 99999999.0
    $lp = GetLocalPlayer()
 
    For $i = 0 To 64
        $currentEntity = _MemoryRead("int", $ClientDll + $EntityList + ($i * 0x10))
        If $currentEntity = 0 Then
            ContinueLoop
        EndIf
        If IsDormant($currentEntity) Then
            ContinueLoop
        EndIf
        If GetTeam($lp) = GetTeam($currentEntity) Then
            ContinueLoop
        EndIf
        If GetHealth($currentEntity) < 1 Then
            ContinueLoop
        EndIf
        $hitbox = GetBonePos($currentEntity, 6)
        $w2sHitbox = WorldToScreen($hitbox)
 
        $distance = DistanceBetweenCross($w2sHitbox.X, $w2sHitbox.Y)
 
        If $distance < $maxDistance Then
            $maxDistance = $distance
            $returnEntity = $currentEntity
        EndIf
    Next
 
    Return $returnEntity
EndFunc
 
Func GetLocalPlayer()
    Return _MemoryRead("int", $ClientDll + $LocalPlayer)
EndFunc
 
Func GetPunchAngle()
    Return _MemoryReadStruct($Vector2D, GetLocalPlayer() + $PunchAngleOffset)
EndFunc
 
Func GetTeam($entity)
    Return _MemoryRead("int", $entity + $TeamOffset)
EndFunc
 
Func GetHealth($entity)
    Return _MemoryRead("int", $entity + $HealthOffset)
EndFunc
 
Func IsDormant($entity)
    Return _MemoryRead("int", $entity + $DormantOffset) = 1
EndFunc
 
Func GetBonePos($entity, $id)
    $bonePtr = _MemoryRead("int", $entity + $BoneMatrixOffset)
    $bMatrix = _MemoryReadStruct($BoneMatrix, $bonePtr + ($id * 0x30))
    $returnVec = DllStructCreate("struct; float X; float Y; float Z;endstruct")
    $returnVec.X = $bMatrix.X
    $returnVec.Y = $bMatrix.Y
    $returnVec.Z = $bMatrix.Z
    Return $returnVec
EndFunc
 
Func DistanceBetweenCross($x, $y)
    $ydist = $y -    @desktopHeight / 2
    $xdist = $x -    @desktopWidth / 2
    Return Sqrt(($ydist ^ 2) + ($xdist ^ 2))
EndFunc

Memory Lib/UDF:

Код:

#cs ----------------------------------------------------------------------------
 
 AutoIt Version: 3.3.14.2
 Author:         YatoDev
 
 Script Function:
    Read and Write memory to another process
 
#ce ----------------------------------------------------------------------------
 
#include-once
 
;PUBLIC CONSTANTS
Global Const $BYTE = "BYTE"
Global Const $BOOL = "BOOLEAN"
Global Const $INT = "INT"
Global Const $FLOAT = "FLOAT"
 
;INTERNAL
Global $__KERNEL32 = DllOpen("kernel32.dll")
Global $__ProcessID = 0
 
;INTERNAL CONST
Global Const $__READ = 0x10
Global Const $__WRITE = 0x28
 
;PUBLIC FUNCTION
Func _MemorySelectProcess($name)
    $__ProcessID = ProcessExists($name)
    Return $__ProcessID <> 0
EndFunc
 
;Determine the base address of a module within process. return 0 == not found
Func _MemoryGetModuleBase($name)
    $struct = _
        'DWORD dwSize;' & _
        'DWORD th32ModuleID;' & _
        'DWORD th32ProcessID;' & _
        'DWORD GlblcntUsage;' & _
        'DWORD ProccntUsage;' & _
        'ptr modBaseAddr;' & _
        'DWORD modBaseSize;' & _
        'ptr hModule;' & _
        'CHAR szModule[256];' & _
        'CHAR szExePath[260]'
    $ModuleEntry = DllStructCreate($struct)
    $SnapShot = DllCall($__KERNEL32, 'ptr', 'CreateToolhelp32Snapshot', 'DWORD', BitOR(0x8, 010), 'DWORD', $__ProcessID)[0]
    if   @error Then Return 0
    $ModuleEntry.dwSize = DllStructGetSize($ModuleEntry)
    $bFirst = DllCall($__KERNEL32, 'BOOL', 'Module32First', 'ptr', $SnapShot, 'ptr', DllStructGetPtr($ModuleEntry))[0]
    if Not $bFirst Or   @error Then Return 0
    While True
        If StringInStr($ModuleEntry.szExePath, $name) Then
            DllCall($__KERNEL32, 'BOOL', 'CloseHandle', 'ptr', $SnapShot)
            Return $ModuleEntry.modBaseAddr
        EndIf
        $bFirst = DllCall($__KERNEL32, 'BOOL', 'Module32Next', 'ptr', $SnapShot, 'ptr', DllStructGetPtr($ModuleEntry))[0]
        if $bFirst == 0x12 Or   @error Then
            DllCall($__KERNEL32, 'BOOL', 'CloseHandle', 'ptr', $SnapShot)
            Return 0
        EndIf
    WEnd
EndFunc
 
;GENERIC READ/Write
Func _MemoryRead($type, $address)
    $hBuffer = DllStructCreate($type)
    $hProc = __OpenProcess($__ProcessID, $__READ)
    DllCall($__KERNEL32, "int", "ReadProcessMemory", "int", $hProc, "int", $address, "ptr", DllStructGetPtr($hBuffer), "int", DllStructGetSize($hBuffer), "int", 0)
    __CloseProcess($hProc)
    if   @error Then Return 0
    Return DllStructGetData($hBuffer,1)
EndFunc
 
Func _MemoryWrite($type, $address, $data)
    $hBuffer = DllStructCreate($type)
    DllStructSetData($hBuffer, 1, $data, 1)
    $hProc = __OpenProcess($__ProcessID, $__WRITE)
    DllCall($__KERNEL32, "int", "WriteProcessMemory", "int", $hProc, "int", $address, "ptr", DllStructGetPtr($hBuffer), "int", DllStructGetSize($hBuffer), "int", 0)
    __CloseProcess($hProc)
    if   @error Then Return False
    Return True
EndFunc
 
;READ/WRITE STRING
Func _MemoryReadString($address, $length)
    $hBuffer = DllStructCreate("char[" & $length & "]")
    $hProc = __OpenProcess($__ProcessID, $__READ)
    DllCall($__KERNEL32, "int", "ReadProcessMemory", "int", $hProc, "int", $address, "ptr", DllStructGetPtr($hBuffer), "int", DllStructGetSize($hBuffer), "int", 0)
    __CloseProcess($hProc)
    if   @error Then Return 0
    $ascii = DllStructGetData($hBuffer, Default)
    Return StringFromASCIIArray($ascii)
EndFunc
 
Func _MemoryWriteString($address, $string)
    $ascii = StringToASCIIArray($string)
    $hBuffer = DllStructCreate("char[" & UBound($ascii) & "]")
    DllStructSetData($hBuffer, 1, $ascii, Default)
    $hProc = __OpenProcess($__ProcessID, $__WRITE)
    DllCall($__KERNEL32, "int", "WriteProcessMemory", "int", $hProc, "int", $address, "ptr", DllStructGetPtr($hBuffer), "int", DllStructGetSize($hBuffer), "int", 0)
    __CloseProcess($hProc)
    if   @error Then Return False
    Return True
EndFunc
 
;READ AND WRITE C STYLED STRUCT
Func _MemoryReadStruct($struct, $address)
    $hProc = __OpenProcess($__ProcessID, $__READ)
    DllCall($__KERNEL32, "int", "ReadProcessMemory", "int", $hProc, "int", $address, "ptr", DllStructGetPtr($struct), "int", DllStructGetSize($struct), "int", 0)
    __CloseProcess($hProc)
    if   @error Then Return 0
    Return $struct
EndFunc
 
Func _MemoryWriteStruct($address, $struct)
    $hProc = __OpenProcess($__ProcessID, $__WRITE)
    DllCall($__KERNEL32, "int", "WriteProcessMemory", "int", $hProc, "int", $address, "ptr", DllStructGetPtr($struct), "int", DllStructGetSize($struct), "int", 0)
    __CloseProcess($hProc)
    if   @error Then Return False
    Return True
EndFunc
 
;PRIVATE FUNCTION
Func __OpenProcess($pid, $access)
    $hProcess = DllCall($__KERNEL32, "int", "OpenProcess", "int", $access, "int", 1, "int", $pid)
    if   @error Then Return 0
    return $hProcess[0]
EndFunc
 
Func __CloseProcess($hProc)
    DllCall($__KERNEL32, "int", "CloseHandle", "int", $hProc)
EndFunc

Вдруг пригодится
Скачать -

Пожалуйста, авторизуйтесь для просмотра ссылки.

//

Пожалуйста, авторизуйтесь для просмотра ссылки.

Johannes · 28 Май 2017

Годно.

shapord1488 · 28 Май 2017

Я думал все уже знают про этот сурс...Ну а так "молодец",что выложил ...Новичкам (пастерам) пригодится

ayygranz · 19 Июн 2017

still work? ty

skizzy · 20 Июн 2017

спасибо)

Mercury1337 · 1 Июл 2017

Для мм-а подойдет?

liebreich · 1 Июл 2017

Mercury1337 написал(а):
Для мм-а подойдет?

логично, если для фейсита этот аим, то для мм тоже

goddammit · 4 Авг 2017

Подскажи что с этим делать, я просто с села. Нажимаю Compile Script и выдает ошибку ссылаясь на YatoMemory.au3

.Dean. · 4 Авг 2017

zalman32 написал(а):
Подскажи что с этим делать, я просто с села.

Учить с++(нет) :whyRly:

YourPollution · 4 Авг 2017

.Dean. написал(а):
Учить с++.

Loahn noop :FailFish:

aimbot для AutoIt

.Dean. · 4 Авг 2017

YourPollution написал(а):
Loahn noop
aimbot для AutoIt

Pilesos zaebal menya palit' suka

iDReeM · 5 Авг 2017

не будет это работать на фейсит. обычный OpenProcess же... надо как минимум через сторонний процесс хендлы ловить, на пряму открыть -палево. (я именно про античит при клиенте, а не на сервере)

ClaSSiKprofit · 5 Авг 2017

Не ебу что такое yatomemory

Kimchi · 22 Авг 2017

Holy fuck, an ahk aimbot for bypassing FaceIT?

+rep +rep +rep

Blick1337 · 22 Авг 2017

$hitbox = GetBonePos($closestEntity, 6)
где ты это говно откапал? голова уже давно не 6

yolo1337 · 22 Авг 2017

iDReeM написал(а):
не будет это работать на фейсит. обычный OpenProcess же... надо как минимум через сторонний процесс хендлы ловить, на пряму открыть -палево. (я именно про античит при клиенте, а не на сервере)

Так никто и не говорит про античит faceit